beer

public

A terminal worth pouring time into

clone

ssh://git@git.notashelf.dev:33/notashelf/beer.git

{
  lib,
  rustPlatform,
  pkg-config,
  makeBinaryWrapper,
  ncurses,
  scdoc,
  installShellFiles,
  wayland,
  libxkbcommon,
  freetype,
  fontconfig,
}: let
  cargoTOML = (lib.importTOML ../Cargo.toml).package.version;
in
  rustPlatform.buildRustPackage (finalAttrs: {
    pname = "beer";
    version = cargoTOML.package.version;

    src = let
      fs = lib.fileset;
      s = ../.;
    in
      fs.toSource {
        root = s;
        fileset = fs.unions [
          (s + /src)
          (s + /Cargo.lock)
          (s + /Cargo.toml)
          (s + /terminfo)
          (s + /doc)
        ];
      };

    cargoLock.lockFile = "${finalAttrs.src}/Cargo.lock";
    enableParallelBuilding = true;

    strictDeps = true;
    nativeBuildInputs = [
      pkg-config
      makeBinaryWrapper
      ncurses # tic
      scdoc # man page generation
      installShellFiles # installManPage
    ];

    buildInputs = [
      wayland
      libxkbcommon
      freetype
      fontconfig
    ];

    # Install the terminfo entry, and make the Wayland/xkb libraries (loaded via
    # dlopen, so not captured by rpath) discoverable at runtime.
    postInstall = ''
      mkdir -p "$out/share/terminfo"
      tic -x -o "$out/share/terminfo" terminfo/beer.info

      # Generate the man pages from their scdoc sources.
      scdoc < doc/beer.1.scd > beer.1
      scdoc < doc/beer.toml.5.scd > beer.toml.5
      installManPage beer.1 beer.toml.5

      wrapProgram "$out/bin/beer" \
        --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [wayland libxkbcommon]}
    '';

    meta = {
      description = "A fast, software-rendered, Wayland-native terminal emulator";
      homepage = "https://github.com/NotAShelf/beer";
      license = lib.licenses.eupl12;
      maintainers = with lib.maintainers; [NotAShelf];
      mainProgram = "beer";
      platforms = lib.platforms.linux;
    };
  })

1	{
2	lib,
3	rustPlatform,
4	pkg-config,
5	makeBinaryWrapper,
6	ncurses,
7	scdoc,
8	installShellFiles,
9	wayland,
10	libxkbcommon,
11	freetype,
12	fontconfig,
13	}: let
14	cargoTOML = (lib.importTOML ../Cargo.toml).package.version;
15	in
16	rustPlatform.buildRustPackage (finalAttrs: {
17	pname = "beer";
18	version = cargoTOML.package.version;
19
20	src = let
21	fs = lib.fileset;
22	s = ../.;
23	in
24	fs.toSource {
25	root = s;
26	fileset = fs.unions [
27	(s + /src)
28	(s + /Cargo.lock)
29	(s + /Cargo.toml)
30	(s + /terminfo)
31	(s + /doc)
32	];
33	};
34
35	cargoLock.lockFile = "${finalAttrs.src}/Cargo.lock";
36	enableParallelBuilding = true;
37
38	strictDeps = true;
39	nativeBuildInputs = [
40	pkg-config
41	makeBinaryWrapper
42	ncurses # tic
43	scdoc # man page generation
44	installShellFiles # installManPage
45	];
46
47	buildInputs = [
48	wayland
49	libxkbcommon
50	freetype
51	fontconfig
52	];
53
54	# Install the terminfo entry, and make the Wayland/xkb libraries (loaded via
55	# dlopen, so not captured by rpath) discoverable at runtime.
56	postInstall = ''
57	mkdir -p "$out/share/terminfo"
58	tic -x -o "$out/share/terminfo" terminfo/beer.info
59
60	# Generate the man pages from their scdoc sources.
61	scdoc < doc/beer.1.scd > beer.1
62	scdoc < doc/beer.toml.5.scd > beer.toml.5
63	installManPage beer.1 beer.toml.5
64
65	wrapProgram "$out/bin/beer" \
66	--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [wayland libxkbcommon]}
67	'';
68
69	meta = {
70	description = "A fast, software-rendered, Wayland-native terminal emulator";
71	homepage = "https://github.com/NotAShelf/beer";
72	license = lib.licenses.eupl12;
73	maintainers = with lib.maintainers; [NotAShelf];
74	mainProgram = "beer";
75	platforms = lib.platforms.linux;
76	};
77	})